Başlıklar ve İçerik
Excel, günümüzde iş dünyasında ve kişisel kullanımda en çok tercih edilen elektronik tablo programlarından biridir. Hemen hemen her sektörde verileri düzenlemek, analiz etmek ve raporlamak için yaygın bir şekilde kullanılır. Excel’in bu geniş kullanımı, güçlü işlevlerine ve formüllerine dayanmaktadır. Bu blog yazısında, Excel’de en çok ihtiyaç duyulan formülleri keşfedeceğiz.
EXCEL’DE İSTATİSTİKSEL HESAPLAR VE FORMÜLLER
Bu bölümde örnek tablodaki değerler ve hücre adresleri dikkate alınarak istatiksel formüller ele alınacaktır.
| Açıklama | Formül (TR) | Formül (ENG) |
|---|---|---|
| Satış Adetlerinin Toplamı | =TOPLA(D2:D10) | =SUM(D2:D10) |
| Satış Adetlerinin Ortalaması | =ORTALAMA(D2:D10) | =AVERAGE(D2:D10) |
| Kaç Adet Kayıt Olduğunu Saydırma | =BAĞ_DEĞ_DOLU_SAY(D2:D10) | =COUNTA(D2:D10) |
| En Düşük Satış Adetini Bulma | =MİN(D2:D10) | =MIN(D2:D10) |
| En Yüksek Satış Adetini Bulma | =MAK(D2:D10) | =MAX(D2:D10) |
| Laptop’ların Toplam Satış Adetini Bulma | =ETOPLA(C2:C10;”Laptop”;D2:D10)) | =SUMIF(C2:C10;”Laptop”;D2:D10)) |
| Trabzonda Kaç Adet Satış Vardır? | =EĞERSAY(B2:B10;”Trabzon”) | =COUNTIF(B2:B10;”Trabzon”) |
| Televizyon Satış Adetlerinin Ortalaması Nedir? | =EĞERORTALAMA(C2:C10;”Televizyon”;D2:D10)) | =AVERAGEIF(C2:C10;”Televizyon”;D2:D10)) |
| Fatma Yıldız’ın Ankara’daki Satışları Toplamı Nedir? | =ÇOKETOPLA(D2:D10;A2:A10;”Fatma Yıldız”;B2:B10;”Ankara”) | =SUMIFS(D2:D10;A2:A10;”Fatma Yıldız”;B2:B10;”Ankara”) |
| İzmir’deki Laptop Satışlarının Ortalaması Nedir? | =ÇOKEĞERORTALAMA(D2:D10;B2:B10;”İzmir”;C2:C10;”Laptop”) | =AVERAGEIFS(D2:D10;B2:B10;”İzmir”;C2:C10;”Laptop”) |
| Ankara’da Kaç Adet Kamera Satışı Vardır? | =ÇOKEĞERSAY(B2:B10;”Ankara”;C2:C10;”Kamera”) | =COUNTIFS(B2:B10;”Ankara”;C2:C10;”Kamera”) |
| Ankarada’daki En Yüksek Kamera Satışı Nedir? | =ÇOKEĞERMAK(D2:D10;C2:C10;”Kamera”;B2:B10;”Ankara”) | =MAXIFS(D2:D10;C2:C10;”Kamera”;B2:B10;”Ankara”) |
| Ankarada’daki En Düşük Kamera Satışı Nedir? | =ÇOKEĞERMIN(D2:D10;C2:C10;”Kamera”;B2:B10;”Ankara”) | =MINIFS(D2:D10;C2:C10;”Kamera”;B2:B10;”Ankara”) |
| Benzersiz Kaç isim var? | =TOPLA(1/EĞERSAY(A2:A10;A2:A10)) | =SUM(1/COUNTIF(A2:A10;A2:A10)) |
EXCEL’DE TARİH FORMÜLLERİ
Bu formüllerde A1 ve A2 yazan yerleri kendi hücre adresiniz ile yer değiştirmelisiniz.
| Açıklama | Girdi | Çıktı | Formül |
|---|---|---|---|
| İki tarih arasındaki Farkı Devirsiz Bulma (YIL) | A1: 21.03.1992 A2: 26.07.2023 | 31 | =ETARİHLİ(A1;A2;”y”) |
| İki tarih arasındaki Farkı Devirsiz Bulma (AY) | A1: 21.03.1992 A2: 26.07.2023 | 376 | =ETARİHLİ(A1;A2;”m”) |
| İki tarih arasındaki Farkı Devirsiz Bulma (GÜN) | A1: 21.03.1992 A2: 26.07.2023 | 11449 | =ETARİHLİ(A1;A2;”d”) |
| İki tarih arasındaki Farkı Bulma (YIL – AY – GÜN) | A1: 21.03.1992 A2: 26.07.2023 | 31 yıl 4 ay 25 gün | =ETARİHLİ(A1;A2;”y”)&” yıl “&ETARİHLİ(A1;A2;”ym”)&” ay “&ETARİHLİ(A1;A2;”md”)&” gün” |
| İki tarih arasındaki Farkı Bulma (Devirli AY) | A1: 21.03.1992 A2: 26.07.2023 | 4 | =ETARİHLİ(D35;E35;”ym”) |
| İki Tarih Arasında Rastgele Tarih Oluşturma (Bu Örnekte 05.03.2018 – 31.12.2020 tarihleri arasında rastgele tarih oluşturulur) | – | Herhangi Bir Tarih | =RASTGELEARADA(TARİH(2018;3;5);TARİH(2020;12;31)) |
| Aralara nokta koymadan tarih yazmak | 1052020 | 1.05.2020 | =SOLDAN(A1;EĞER(UZUNLUK(A1)=7;1;2))&”.”&PARÇAAL(A1;EĞER(UZUNLUK(A1)=7;2;3);2)&”.”&SAĞDAN(A1;4) |
| Bir tarihin Ayını metin olarak getirme | 21.03.2023 | Mart | =METNEÇEVİR(A1;”aaaa”) |
| Bir tarihin hangi gün olduğunu getirme | 21.03.2023 | Salı | =METNEÇEVİR(A1;”gggg”) |
| Bir tarihin yılını getirme | 21.03.2023 | 2023 | =YIL(A1) |
| Bir yıldaki tüm tarihleri çıkarır | – | – | =SIRALI(52;7;”02.01.2023″) |
| Bir tarihin hangi çeyrek diliminde olduğunu bulma | 21.03.2023 | Ç1 | =”Ç”&YUKARIYUVARLA(AY(A1)/3;0) |
| İçinde bulunduğunuz tarihi yazar | – | 21.03.2023 | =BUGÜN() |
| İçinde bulunduğunuz saati yazar | – | 07:51 | =ŞİMDİ() |
EXCEL’DE SAAT FORMÜLLERİ
Bu formüllerde A1 ve A2 yazan yerleri kendi hücre adresiniz ile yer değiştirmelisiniz.
| Açıklama | Girdi | Çıktı | Formül |
|---|---|---|---|
| Normal sayıyı saate çevirme | 17,51 | 17:30:00 | =ZAMAN(A1;(A1-TAMSAYI(A1))*60;0) |
| Saati Normal Sayıya Çevirme | 17:51:00 | 17,85 | =A1*24 |
| Numerik Gün değerini saate çevirme | 0,6 | 14,4 | =A1*24 |
| Numerik Saat değerini Güne çevirme | 10,9 | 0,45 | =A1/24 |
| Numerik Saat değerini Dakikaya çevirme | 1,59 | 95,4 | =A1*60 |
| Numerik Dakika değerini Saate çevirme | 18 | 0,3 | =A1/60 |
| Numerik Gün Değerini Gün-Saat-Dakika cinsinden yazma | 12,66 | 12 gün 15 saat 50,5 Dakika | =TAMSAYI(A1)&” gün “& TAMSAYI((A1-TAMSAYI(A1))24)&” saat “& YUKARIYUVARLA((((A1-TAMSAYI(A1))24)-TAMSAYI((A1-TAMSAYI(A1))24))60;1)&” Dakika” |
| Numerik Saat değerini Saat-Dakika cinsinden yazma | 10,9 | 10 saat 54 dakika | =TAMSAYI(A1)&” saat “&(A1-TAMSAYI(A1))*60&” dakika” |
EXCEL’DE VERİ ÇEKME/BULMA FORMÜLLERİ
Bu bölümde örnek tablodaki değerler ve hücre adresleri dikkate alınarak veri çekme formüller ele alınacaktır. Genel olarak bu bölümde DÜŞEYARA, İNDİS, KAÇINCI, ÇAPRAZARA gibi formüller gösterilecektir.
| Açıklama | Formül |
|---|---|
| Yeşil tabloda ismi yazılan kişinin telefon numarasını mavi tablodan bakıp getirme (DÜŞEYARA) | =DÜŞEYARA(A2;$A$4:$C$14;3;0) |
| Yeşil tabloda ismi yazılan kişinin telefon numarasını mavi tablodan bakıp getirme (İNDİS-KAÇINCI) – 1. Yöntem | =İNDİS($C$4:$C$14;KAÇINCI(A2;$A$4:$A$14;0)) |
| Yeşil tabloda ismi yazılan kişinin telefon numarasını mavi tablodan bakıp getirme (İNDİS-KAÇINCI) – 2. Yöntem | =İNDİS($A$4:$C$14;KAÇINCI(A2;$A$4:$A$14;0);3) |
| Yeşil tabloda ismi yazılan kişinin telefon numarasını mavi tablodan bakıp getirme (ÇAPRAZARA) | =ÇAPRAZARA(A2;$A$4:$A$14;$C$4:$C$14) |
| Sayfa adını hücreye çeken formül | =PARÇAAL(HÜCRE(“dosyaadı”;A1);BUL(“]”;HÜCRE(“dosyaadı”;A1))+1;31) |
EXCEL’DE METİNSEL FORMÜLLER
Bu formüllerde A1 yazan yerleri kendi hücre adresiniz ile yer değiştirmelisiniz.
| Açıklama | Girdi | Çıktı | Formül |
|---|---|---|---|
| Bir metnin bütün harflerini büyük ve ingilizce karakterli yapma | salih_hocaoglu | SALIH_HOCAOGLU | =YERİNEKOY(YERİNEKOY(YERİNEKOY(YERİNEKOY(YERİNEKOY(YERİNEKOY(BÜYÜKHARF(A1);”Ç”;”C”);”İ”;”I”);”Ö”;”O”);”Ü”;”U”);”Ğ”;”G”);”Ş”;”S”) |
| Bir metinde belli bir karaktere kadar olan kısmı alma | salih-hocaoğlu | salih | =SOLDAN(A1;(BUL(“-“;A1;1)-1)) |
| Bir metinde belli bir karakterden sonraki kısmı alma | salih-hocaoğlu | hocaoğlu | =PARÇAAL(A1;BUL(“-“;A1)+1;256) |
| Bir metni 3’e parçalama (Sağdaki Metin) | Mehmet Akif Ersoy | Mehmet | =SOLDAN(A1;MBUL(” “;A1)) |
| Bir metni 3’e parçalama (Ortadaki Metin) | Mehmet Akif Ersoy | Akif | =PARÇAAL(A1;MBUL(” “;A1)+1;MBUL(” “;A1;MBUL(” “;A1;1)+1)-MBUL(” “;A1;1)) |
| Bir metni 3’e parçalama (Soldaki Metin) | Mehmet Akif Ersoy | Ersoy | =SAĞDAN(A1;UZUNLUK(A1)-MBUL(” “;A1;MBUL(” “;A1;1)+1)) |
| Bir metnin bütün harflerini büyük harfe çevirir | SaliH hOCaoğLu | SALİH HOCAOĞLU | =BÜYÜKHARF(A1) |
| Bir metnin bütün harflerini küçük harfe çevirir | SaliH hOCaoğLu | salih hocaoğlu | =KÜÇÜKHARF(A1) |
| Bir kelimenin ilk harfini büyük diğer harflerini küçük yapar | SaliH hOCaoğLu | Salih Hocaoğlu | =YAZIM.DÜZENİ(A1) |
| Bir metindeki fazlalık boşlukları kaldırır ve aşağı inen metinleri yukarı getirir | Benim adım Salih | Benim adım Salih | =TEMİZ(KIRP(A1)) |
EXCEL’DE KOŞULLU FORMÜLLER
Bu formüllerde A1 yazan yerleri kendi hücre adresiniz ile yer değiştirmelisiniz.
| Açıklama | Formül |
|---|---|
| Eğer hücre boşsa “Boş” yaz, boş değilse “Boş Değil” yaz. | =EĞER(A1<>””;”Boş Değil”;”Boş”) |
| Hücre değeri 45’e eşit ve büyükse “Başarılı” değilse “Kaldı” yaz | =EĞER(A1>=45;”Başarılı”;”Kaldı”) |
| Eğer Değer; 90’dan büyükse, “Pekiyi” (90 – 70] arasındaysa, “İyi” (70 – 60] arasındaysa, “Orta” (60 – 45] arasındaysa, “Geçer” 45’ten küçükse, “Başarısız” yaz. | =EĞER(A1>90;”Pekiyi”;EĞER(A1>=70;”İyi”;EĞER(A1>=60;”Orta”;EĞER(A1>=45;”Geçer”;”Başarısız”)))) |
EXCEL’DE HÜCRE BİÇİMLENDİRME FORMÜLLERİ
Excel’de bir hücrenin biçimlendirmesi değiştirerek verinin görünümünü değiştirebiliriz. Örneğin 01.01.2023 tarihini sdece biçimlendirme kodlarını kullanarak “Oca 23” şeklinde gösterebiliriz. Biçimlendirme kodları hem Hücreleri Biçimlendir penceresinde hem de METNEÇEVİR (TEXT) işlevinde kullanılabilir.
Hücreleri Biçimlendir
Hücreleri biçimlendir penceresinde kodlama yapmak için;
- İstediğiniz hücreleri seçin
- Sağ tıklayın ve Hücreleri Biçimlendir seçeneğini seçin.
- Ya da CTRL+1 kısayolunu kullanarakta Hücreleri Biçimlendir penceresine gidebilirsiniz.
- İsteğe Uyarlanmış seçeneğini seçiniz
- İstediğiniz kodlamayı buradaki Tür kutucuğuna yapabilirsiniz.
| Açıklama | Formül |
|---|---|
| Sayıları Bin, Milyon veya Milyar şeklinde gruplamak için kullanılır. Örneğin: 2.100.000 sayısını 2,1 M şeklinde yazar | [<999950]₺0.,0″K”;[<999950000]₺0..,0″M”;0…,0″B” |
| Pozitif sayıları yeşil, negatif sayıları kırmızıya boyar, Sıfır’a eşit sayılarda biçimlendirme yapmaz. | [Renk10] #.##0 “▲”;[Kırmızı]-#.##0 “▼”;#.##0 |
| Her zaman metnin sonuna “:” iki nokta üst üste koyar. | @* : |
| Bir tarih verisini biçimlendirme (g: Gün, a: Ay, y: Yıl) | gg aaaa yyyy |
| Saat verisini biçimlendirme (s: saat, d: Dakika, n: Saniye) | ss:dd:nn |
| Saat verisine salise ekleme | ss:dd:nn,000 |
| Saati devirsiz hale çevirme. Bu biçimlendirmeyle 24 saati aşan saatleri gösterebilirsiniz. Örn: 54:23:56 | [s]:dd:nn |
EXCEL VERİ DOĞRULAMA FORMÜLLERİ
Bu listede kendinize özel veri doğrulama kulları oluşturabileceğiniz formüller bulunur. Bu formüllerde A1 yazan yerleri kendi hücre adresiniz ile yer değiştirmelisiniz.
| Açıklama | Formül |
|---|---|
| Bir hücrede doğru telefon numarası formatı girilip girilmediğinin kontrolünü sağlar (10 haneli) | =VE(EĞER(UZUNLUK(A1)=10;”DOĞRU”;”YANLIŞ”);ESAYIYSA(A1)) |
| Bir hücrede doğru mail adresi formatı girilip girilmediğinin kontrolünü sağlar. | =VE(BUL(“@”;A1);BUL(“.”;A1);EHATALIYSA(BUL(” “;A1))) |
| Bir hücreye girilen veri de rakam olup olmadığını kontrol eder. | =DEĞİL(BAĞ_DEĞ_SAY(MBUL({0;1;2;3;4;5;6;7;8;9};A1))>0) |
Şablonlarımıza da Göz atmak isterseniz Aşağıdaki linkleri kullanabilirsiniz;